Kubotek Forum

Or use this utility to quickly set the CCP and Xform level options:


rem xfopt.kxl
rem utility to set xform and cut-copy-paste level options
rem Dana Hague 3/31/11

// (0xAAB8) Toggle the display of toolbar 13
//CallFunc 43705

GET XFLEVOPT, xopt
rem 0 is entity level, 1 is active level
get CCPGroup, ccpgopt
rem 0 is single level, 1 is original levels
get CCPParent, ccppopt
rem 0 is root levels, 1 is active level

IF (xopt == 0)
    $xopt = "Entity"
IF (xopt == 1)
    $xopt = "Active"
IF (ccppopt == 0)
    $ccppopt = "Root"
IF (ccppopt == 1)
    $ccppopt = "Active"
IF (ccpgopt == 0)
    $ccpgopt = "-Single"
IF (ccpgopt == 1)
    $ccpgopt = "+Original"

$menustring = "Select level option for XFORM ( "
STRCAT $menustring, $xopt
STRCAT $menustring, ") or CCP ("
STRCAT $menustring, $ccppopt
STRCAT $menustring, $ccpgopt
STRCAT $menustring, ")"

:menu
GETMENU $menustring, "--XFORM:--|Entity|Active| |---CCP:---|Root-Single|Root+Orig|Active-Single|Active+Orig",
ON (@key+6) GOTO end, end, end, end, end, end, end, menu, xent, xact, menu, menu, ccprs, ccpro, ccpas, ccpao

:xent
SET XFLEVOPT, 0
PROMPT "XFORM set to entity level."
goto optchosen

:xact
SET XFLEVOPT, 1
PROMPT "XFORM set to active level."
goto optchosen

:ccprs
SET CCPParent, 0
SET CCPGroup, 0
PROMPT "CCP set to Root - Single level."
goto optchosen

:ccpro
SET CCPParent, 0
SET CCPGroup, 1
PROMPT "CCP set to Root plus Original sublevels."
goto optchosen

:ccpas
SET CCPParent, 1
SET CCPGroup, 0
PROMPT "CCP set to Active - Single level."
goto optchosen

:ccpao
SET CCPParent, 1
SET CCPGroup, 1
PROMPT "CCP set to Active plus Original sublevels."
goto optchosen

:optchosen
WAIT 2

:end
CLEAR $menustring, $xopt, $ccpgopt, $ccppopt
CLEAR xopt, ccppopt, ccpgopt